boe.pres.k12.wv.us/boe.pres.k12.wv.us.zip/boe.pres.k12.wv.us/Utilities/Xerox Workcentre 5335/Windows Scan/32-bit_x86/Russian/cpsimage.cab/data/docio/docFormatService.elf

Text File | 2009-03-16 | 6KB | 211 lines

// $Id: docFormatService.elf,v 1.6 2008/07/10 20:25:53 campanel Exp $

LoadClasses(filename:"xeng");
#load "sys/stdio.elf";
#load "docio/doctransforms.elf";

PROCEDURE makeAddFromDelete (LIST deleteList, INTEGER addLength) RETURNS (LIST addList)
{
    INTEGER ii;
    INTEGER index;

    if (doTrace)
        print "Running makeAddFromDelete";
    // put all pages on the list
    for (ii=1; ii<=addLength; ii++) {
        /* make a copy of ii at current value; list holds a reference to object */
        addList.insert(obj: ii.Copy());
    }
    addList.sort( numeric: TRUE, descending: FALSE);

    // make sure the objects are removed from the list "far end" first
    deleteList.sort( numeric: TRUE, descending: FALSE);
    // now remove any page marked as delete
    /*
    foreach ( deleteList: pn ) {
        print "Removing "+pn;
        addList.remove( entry: pn - 1);
    }
    */

    INTEGER i;
    foreach ( deleteList: pn ) {
        print "Removing "+pn;
        index = pn.Copy();
        for(i = 0; i < addList.length(); i++)
        {
            if (addList.ref(entry: i) == index)
            {
                addList.remove(entry: i);
            }
        }
    }
}

PROCEDURE docAddAllPages (DOCUMENTREADER dr, DOCUMENTWRITER dw, BOOLEAN doTrace)
                       RETURNS (BOOLEAN success, INTEGER pgcnt)
{
    INTEGER srcPgs = dr.getPageCount();
    INTEGER ii = 0;
    INTEGER offset;
    XIPIMAGE curPg;
    XIPIMAGE destimg;
    BOOLEAN usingSameImg;

    if (doTrace)
        print "Running docAddAllPages";

    pgcnt = 0;
    for (ii = 0; ii<srcPgs; ii++) {
        offset = ii+1;
        if (doTrace) print "    process page "+offset;
        curPg = dr.getPage( pgnum: offset );
        if (!curPg) {
            if (doTrace)
                print "    Could not acquire page image";
            success = FALSE;
            return;
        }
        TransformPage (inpage: curPg, todoc: dw, doTrace: doTrace)
            RETURNS (outpage: destimg, isOriginal: usingSameImg);
        if (!destimg) {
            if (doTrace)
                print "    Transfomation of page failed";
            success = FALSE;
            return;
        }
        if (doTrace)
            print "    appending page image from TransformPage to DOCUMENTWRITER";
        pgcnt = dw.appendPage(pgImg: destimg);
    }

    success = TRUE;
}


PROCEDURE docAddSelectPages (DOCUMENTREADER dr, DOCUMENTWRITER dw, LIST pageList, BOOLEAN doTrace)
                       RETURNS (BOOLEAN success, INTEGER pgcnt)
{
    INTEGER srcPgs = dr.getPageCount();
    INTEGER ii = 0;
    XIPIMAGE curPg;
    XIPIMAGE destimg;
    BOOLEAN usingSameImg;

    if (doTrace)
        print "Running docAddSelectPages";

    foreach ( pageList : index) {
        if (doTrace) print "    process page "+index;
        if (index > srcPgs) {
            if (doTrace)
                print "    Page index exceeds page count";
            success = FALSE;
            return;
        }
        curPg = dr.getPage( pgnum: index );
        if (!curPg) {
            if (doTrace)
                print "    Could not acquire page image";
            success = FALSE;
            return;
        }
        TransformPage (inpage: curPg, todoc: dw, doTrace: doTrace)
            RETURNS (outpage: destimg, isOriginal: usingSameImg);
        if (!destimg) {
            if (doTrace)
                print "    Transfomation of page failed";
            success = FALSE;
            return;
        }
        if (doTrace)
            print "    appending page image from TransformPage to DOCUMENTWRITER";
        pgcnt = dw.appendPage(pgImg: destimg);
    }

    success = TRUE;
}



/**********************************************************************************/
/*****************************   SCRIPT ENTRY *************************************/
/**********************************************************************************/
BOOLEAN doTrace = FALSE;
BOOLEAN success = FALSE;
INTEGER destPgCnt = 0;

/* Here are the import variables */
IMPORT INTEGER debugLevel = 0;

IMPORT STRING srcFile;
IMPORT STRING destFile;
IMPORT STRING destFormat;
IMPORT STRING destSubtype = "none";

IMPORT LIST pagesToRemove;

if (debugLevel & 2) {
    doTrace = TRUE;
    print "***** Running docFormatService *****";
}

/* Test input vars */
if (!srcFile) {
    SetStatus(op: "stop", msg: "No source image was provided");
    return;
}
if (!destFile) {
    SetStatus(op: "stop", msg: "No destination image was provided");
    return;
}

if (debugLevel & 4)
    help "var";

DOCUMENTREADER drrd = CreateDocumentReader( filename: srcFile );
if (!drrd) {
    SetStatus(op: "stop", msg: "Failed to create DOCUMENTREADER from "+srcFile );
    return;
}

if (!destFormat) {
    DOCUMENTWRITER dwwt = CreateDocumentWriter( filename: destFile );
} else {
    DOCUMENTWRITER dwwt = CreateDocumentWriter( filename: destFile, format: destFormat, subtype: destSubtype );
}

if (!pagesToRemove) {
    docAddAllPages (dr: drrd, dw: dwwt, doTrace: doTrace)
                       RETURNS (success: success, pgcnt: destPgCnt);
} else {
    LIST addPages;
    INTEGER pgcnt = drrd.getPageCount();

    if (doTrace)
        print "    Assemble list of pages to delete";

    makeAddFromDelete (deleteList: pagesToRemove, addLength: pgcnt)
                       RETURNS (addList: addPages);

    if (debugLevel & 4) {
        help "var";
        print addPages;
    }

    docAddSelectPages (dr: drrd, dw: dwwt, pageList: addPages, doTrace: doTrace)
                       RETURNS (success: success, pgcnt: destPgCnt);
}


if (debugLevel & 4)
    help "var";

if (!success) {
    SetStatus(op: "stop", msg: "Document conversion NOT successful. Converted pages = "+destPgCnt);
    return;
}

if (doTrace)
    print "    Document conversion successful. Converted pages = "+destPgCnt;